いろんなプログラムからメール送受信に使えるBASP21について。

メール送受信入門 — 2017-01-12T16:30:53+09:00

Excelでメールを送受信するVBAプログラムは、
汎用コンポーネントのBASP21を使っています。

実はBASP21は優れもので、EXCELのVBAだけではなく、

VBScriptやWSH(Windows Scripting Host)など、他のプログラミング言語からも利用することができます。

もちろんVBAを使えるAccessや、より高機能なVB(Visual Basic)からも使えます。

その中でも、Windowsパソコンで一番簡単なのは、VBScriptかWSHでしょうね。

特にソフトウェアを用意することなく、
買ったばかりのパソコンでも、すぐに実行できますから。

プログラムもメモ帳のようなテキストエディタがあれば作成できるし、

プログラムの実行も、ファイルをダブルクリックするだけです。

例えば、VBScriptでプログラムを作成するなら、
まずテキストエディタでプログラムを書きます。

プログラム自体は、ほとんどVBAと同じ書き方です。
構文や関数などほぼ同じ。

あとは保存する時にファイルの拡張子を「.vbs」にするだけ。

そして拡張子「.vbs」のファイルをダブルクリックすると、
プログラムが実行されますよ。

簡単ですよね。実にシンプルです。

私はこの手軽さが大好きですｗ

プログラムから簡単なメールを送信したり、
受信したメールをテキストファイルで読む程度なら、

VBScriptでも十分に開発することができます。

プログラムの中に文章とメルアドを直接書いておき、
ダブルクリックするだけで送信！みたいな使い方。

また、Accessのようなデータベースを使うメリットは、
テーブルに保存したデータを利用して、

個別に内容を変えたメールを送信したり、
クエリを使っていろんな条件で絞り込んだリストにメールを送れることです。

メールの受信でもメリットがあります。

VBAでメールの内容を取り出したり、抽出したり、
SQL文を使って各テーブルにデータを分けて保存することができます。

Accessを窓口として、より本格的なデータベースに保存することも可能です。

]]>

ExcelVBAでメールを受信するプログラムは2段階処理が必要。

メール送受信入門 — 2016-01-12T19:46:59+09:00

Excelでメールを受信するVBAプログラムは、手順が2段階になります。

実際にプログラミングする前に、概要を説明しておきます。

ExcelのVBAからも利用できるコンポーネントのBASP21では、
メールの送受信に関するメソッドが2つあります。

それはRcvMail(メール受信)とReadMail(メール読込み)です。

まずRcvMailメソッドは、POP3プロトコルでメールを受信することができます。

メールサーバーからメールを受信して、
パソコン内の指定したフォルダに、テキスト形式で保存します。

どのフォルダに保存するかは、ディレクトリ名を指定することで、簡単に設定できます。

フォルダ内にはメール1件につき、1つのテキストファイルが作成されます。

またRcvMailには、様々な引数が用意されています。
RcvMail(svname,user,pass,command,dirname)

これらの引数を指定することで、メール受信に関する細かい設定が可能です。

例えば、メール数を調べたり、一度の受信数を制限したり、
メールサーバーのメールを削除するか残すかなどの設定もできます。

件名や送信者を調べることも可能です。

ということは、特定の送信者からのメールだけを選別して受信することもできるのです。

だからちょっと工夫することで、スパムメール、迷惑メールは100％防げますよ。

これがメール受信プログラムを、わざわざ独自に作る大きなメリットなのです。

次にReadMailメソッドで、フォルダに保存されたメールの中身を読み込みます。

受信したテキストファイルの中身には、メールの本文を含め、ヘッダーや添付ファイル名
などの情報が記載されています。

これらの情報がメソッドからの戻り値として、配列で返されます。

あとはプログラムの中で配列から情報を取り出して利用します。

例えば、Excelのセルに表示したり、Accessなどのデータベースに保存することが可能です。

データを変数の中に取り込んでしまえば、あとの加工は自由自在です。

送信者ごとに分類したり、メール本文から特定の情報を取り出す、解析も簡単。

アイデア次第では、メールだけでいろんなことが出来ます。

会社の業務レポートをデータベース化したり、
商品の受注データを取り込めば、販売管理や顧客管理ツールなどもメールでできてしまいます。

これが二つ目の大きなメリットになるわけです。

ps:
最終的にはメールで受信すれば良いわけで、Webフォームから送ったメールでもOKなんです。

わざわざWeb上のデータベースを使った大掛かりなショッピングカートを作らなくても、
既存のフォームにちょっと手を加えるだけで、ネットショップの仕組みが出来ますよ。

具体的なメール受信プログラムについては、次回からの記事に掲載します。

]]>

Excelでメールを受信するための準備をする。

メール送受信入門 — 2014-12-28T14:11:56+09:00

Excel(エクセル)でメールを受信するプログラムを作成する前に、もう一度確認して欲しいことがあります。

全てこれまでの記事に書いた事ばかりですが、

とても重要なので、再度まとめておきます。

この「メール送信・受信プログラミング初心者入門」を、

メニューの順番通りにステップを進めていた場合は、特に問題ありません。

もうすぐにExcelで受信のプログラミングが出来ます。

しかし、いきなりメール受信のプログラムのステップから入っている場合は、

要チェックです。

(1)マイクロソフト社のExcelがインストールされているか、確認してください。
これからExcelでプログラミングするのですから、当然必要ですよね。

(2)BASP21がインストールされているか、確認してください。
BASP21の機能でメールの送受信を行うためです。

まだの方は、以下の記事を参考にしてください。

BASP21をインストールする
メール送受信の機能を追加するため、「BASP21」をインストールする。

(3)受信用のReceiveフォルダがあるか、確認してください。

手順通り進めていれば、Excelのファイル「メール送受信.xls」がある
「mailPG」フォルダの中に、「Receive」というフォルダが作成されているはずです。

Step1・フォルダを作成する
メール送受信を行なうため、プログラムを格納するフォルダを作成する。

(4)受信用のフォーム、ワークシートは作成しましたか？
受信用のフォームとワークシートは、既に以下のステップで作成済みです。

Step7・受信フォームを作成する
Excelでメール受信用のユーザーフォームを作成する。

こんなフォームが表示されればOKです。

まだの方は、ステップを戻って作成してください。

(5)受信専用のメルアドを1つ準備する。
プログラムから直接、メールボックスを操作するので、
普段使っているメールアドレスだと、いろいろ不都合です。

プログラムテスト用のメールアドレスが必要です。

テストには不具合(バグ)がつきものです。

何が起こるかわからないので、必ず別にメルアドを用意してください。

詳しくは、以下の記事を参考にしてください。

メールアドレスを準備
メール送受信で利用するメールアドレスを用意する。

以上、ここまで準備出来たらOKです。

いよいよExcelで、メールを受信するプログラミングが出来ます。

]]>

Excelでメール受信するプログラムのメリットについて。

メール送受信入門 — 2010-07-23T07:28:54+09:00

Excelでメール受信するVBAプログラムには、どんなメリットがあるのか、どんな使い方ができるのか、ほんの一部ですが紹介します。

あらかじめメリットを理解していたほうが、プログラミングの学習も、やる気が出ると思います。

(1)スパムメールをほぼ100％防止できる。
プログラムを使えば、送信者や件名、本文を判断して、あなた「独自のルール」で、メールを受信できます。

例えば、受信したい送信者のメールアドレスを、あらかじめ登録しておきます。

メールを受信する時に、登録しておいたメールアドレスを参照し、一致すれば受信します。

すると、それ以外のメール(スパムメール)は、シャットアウトできます。

複数の条件を組み合わせれば、迷惑メールをほぼ完全に防げます。

メールサーバーには、従来どおりスパムメールが届くかも知れません。

でも受信の段階で、自動的に除けるわけです。

(2)ネットショップの受注データをデータベース化できる。
自社でネットショップを運営している場合は、メールで受注しているケースが多いと思います。

そして後は、手作業で処理しているのではないでしょうか？

大手のショッピングモールなどでは、受注データをネット上で利用できたり、CSVとしてダウンロードできることもあります。

また、自社でシステムを構築する場合でも、MySQLなどのWeb上で動作するデータベースを使うと、同じようなことができます。

しかし自社で開発するとなると、それなりに高度な知識が必要になります。

ソフトウェア開発会社に外注すると高いです。

そのため小さな会社では、受注メールを見て、宛先を書いたり(出力)、伝票を作成したり、返信メールを送るといった業務が、手作業で行なわれています。

それに受注データは、データベース化されていないことが多いです。

実はメール受信の部分をプログラミングすれば、これらの作業は、ほぼ自動的に行なえます。

MySQLなども不要なため、比較的簡単にシステムを構築できます。

今運用しているネットショップはそのままで、メール受信の部分だけプログラミングできることも、大きなメリットです。

(3)アンケートの集計ができる。
Web上でアンケートフォームに入力してもらい、メールで送ることは、CGIやPHPを使えば簡単にできます。

あとはメールを受信するプログラムを使い、受信したデータを、ExcelやAccessなどで、自動的に集計することができます。

(4)氏名やメールアドレスの登録ができる。(メルマガなどに利用)
これまでに紹介したメール送信の機能を使えば、オリジナルのメールマガジンを発行したり、ステップメールを送ることができます。

でも氏名やメールアドレスの登録が面倒ですよね？

プログラムでメール受信ができるようになれば、メルマガ登録フォームに入力されたデータを、メールで受け取り、ExcelやAccessなどで管理できるようになります。

つまりオリジナルのメルマガ登録が、自動的にできるわけです。

(5)Accessに移植しやすい。
メール送信に関しては、Excelを使うことに大きなメリットがありました。

普段使い慣れているExcelは、送信先のデータを加工しやすいからです。

しかしメール受信に関しては、データベースソフトであるAccessのほうが、圧倒的に便利です。

Accessを使うと、検索、抽出、集計が、クエリで簡単にできます。

そのため当講座でも、Excelでのメール受信は、基本的な部分だけにします。

そしてすぐにAccess版に続くような形式にしたいと思います。

でもExcelでの学習は、無駄にはなりません。

AccessとExcelでは、VBAを使うので、プログラムがほとんど同じだからです。

扱う部品が違うので、多少は違うのですが、Excel版を理解していると、Access版に移植しやすいのは確かです。

Excel版のプログラムが分からないと、Access版も分かりません。

【補足】
今回紹介した様なことを実現するのは、一見難しそうに感じるかも知れません。

実はどれも基本は同じです。

メールサーバーからメールを受信する。
↓
送信者や件名、本文の内容を解析する。
↓
どう処理するか決める。

たったこれだけです。

したがって、個々のプログラムを詳しく解説するというよりは、全体として共通する部分のプログラムを紹介します。

あとは目的に合わせて、カスタマイズ出来るようになります。

]]>

Excelでメール受信するプログラムについて。

メール送受信入門 — 2010-07-22T07:02:07+09:00

Excelでメール受信が出来るようになると、活用範囲がもっともっと大きく広がります。

当無料講座では、これまでにExcelからメール送信するプログラムを中心に紹介してきました。

でも私の個人的な意見としては、「メール受信」こそが、ぜひ活用していただきたい機能なのです。

もちろんメールは、受信と送信の両輪です。

どちらか一つでは、十分に機能を果たせません。

これまでに紹介したメール送信だけでも、かなり便利になったと思います。

感謝のメールもいただいています。

それにメール受信の機能をプラスすれば、鬼に金棒です。

ビジネスやプライベートで、メールをもっと活用できるようになります。

メールを受信するプログラムのメリットについては、次回に詳しく説明します。

ほんの少しだけ例を上げると、

・スパムメールをほぼ100％防止できる。
・ネットショップの受注データをデータベース化できる。
・アンケートの集計ができる。
・氏名やメールアドレスの登録ができる。(メルマガなどに利用)

などがあります。

メール受信は、アイデア次第で、もっと可能性が広がっています。

私はこれまでに、上記のようなメール受信のメリットを活かしたシステム開発を、何件か手がけたことがあります。

詳しくは話せませんが、官公庁関連や旅行業界などです。

ユーザー様には「凄く便利になった」、「時間が短縮された」と喜んでいただきました。

それまで手作業で行なっていた仕事が、全て自動化できたのですから、当然です。

そこで当講座では、あなたも自分自身でメール受信のプログラムを開発し、自由自在にカスタマイズできるように、お手伝いしたいと思います。

お楽しみに！

]]>

Excelからメール送信するVBAプログラムのまとめ。

メール送受信入門 — 2010-07-16T07:33:46+09:00

今回は、Excelからメール送信するVBAプログラミングのまとめです。

まず、Excelからメール送信できると、何が便利なのか考えてみましょう。

表計算ソフトのExcelは、もっとも身近なソフトウェアの一つです。

ほとんどの Windows パソコンにインストールされています。

そのためプログラムの開発環境が、既に準備されている状態です。

Excelがインストール済みなら、新たな費用は不要です。

またExcelは、簡単に操作できること、多くの人が使い慣れていることもメリットです。

今ではほとんどの人が、Excelにデータを入力したり、編集することができます。

日頃から使い慣れているExcelで、メール送信ができれば、活用範囲が大きく広がります。

そこでこの無料講座では、Excelからメール送信するVBAプログラムの作り方を紹介しました。

この無料講座のスキルを習得すると、Excelで以下のようなことが出来るようになります。

■メール送信について
・通常のメール送信(個別に)
・一括送信
・送信範囲を指定して送信
・タイトルや本文にデータを挿入できる
・添付ファイルを指定して送信

挿入するデータや添付ファイルは、送信相手ごとに変えることができます。

それに添付ファイルを複数指定することも可能です。

■ステップメールについて
・タイトル、文章をステップごとに指定できる
・送信間隔をステップごとに指定できる

ステップメールには、通常のメール送信の機能も含めることができます。

以上のようなことが出来るようになれば、メール送信に関しては、一通りの機能を実現できたと思います。

あなたが実際にプログラミングすれば、カスタマイズする力も身に付いているハズです。

これ以上複雑なメール送信なら、Excelではなく、Accessなどのデータベースを使ったほうが便利です。

例えば、Accessのクエリを使うと、

高度な条件で抽出した名簿に対して、メール送信するようなことが可能になります。

また売上管理システムと、メール送信システムを連動させれば、

「最近、ある一定金額以上を購入したことのある、お得意様だけ」に特別なメールを送信することも可能です。

もちろんExcelでも、「並べ替え」である程度のことはできます。

この無料講座で紹介したVBAプログラムでは、セルの番地を見ているので、並べ替えても大丈夫です。

もちろん並べ替える時は、行単位で並べ替えます。

少なくとも氏名とメールアドレスはセットです。

コピー&ペーストしても並べ替えることができます。

余裕のある人は試してみてください。

しかし並べ替えや抽出が複雑になると、Accessのほうが便利なのは確かです。

そこでメール送信の続きとして、Access版も用意する予定です。お楽しみに！

・メール送信・受信プログラミング初心者入門(Access版)

今はまだ準備中ですが、Excelでの「メール受信」が完了した頃に、本格的に始める予定です。

]]>

Excelでステップメールを送信する時に、送信間隔を設定するプログラムの解説。

メール送受信入門 — 2010-07-15T08:14:23+09:00

今回は、Excelからステップメールを送信する時に、送信間隔を設定するVBAプログラムについて、詳しく解説します。

実は既に以下のステップで、ほとんど説明済みです。
・Step60で完成図
・Step61でプログラムのヒント
・Step62で解答例

そこで今回は、大事なポイントだけを、解説することにします。

また以前のステップと重なっている説明もあるのですが、ご了承ください。

繰り返し書いているということは、それだけ重要な部分です。

特に(9)は必ず読んでください。今回の中では一番重要です。

(1)送信間隔を代入するための変数(配列)を宣言している部分です。

・宣言セクション

Option Explicit

省略
Dim intervalArray() As Integer '送信間隔

変数の有効範囲に気をつけてください。

この変数は、複数のプロシージャで共通して使います。

したがって宣言セクションで、変数の宣言をしています。

また送信間隔は、ステップごとに異なります。

複数のデータを同じ変数名で扱いたいので、配列にしているのがポイントです。

(2)メールの送信間隔を取得する配列の要素数を変更している部分です。

ReDim intervalArray(1 To maxStep)

配列は1から始まり、最大ステップ数までになっているのがポイントです。

理由は、配列とステップの番号を揃えるためです。

(3)メールの送信間隔を、Excelのワークシートから取得している部分です。

intervalArray(i) = CInt(Trim(Sheets("文章").Range("D" & i + 1).Value))

送信間隔は、配列を使って、あらかじめ取得しておきます。

これは文章とタイトルの場合と同じです。

変数 i には、行番号が入っています。iが変化することで、異なる行の値を取得できます。

Trim関数を使っているのは、前後の空白を取り除くためです。

(4)メールの最終送信日を取得し、次の送信日を計算している部分です。

'最終送信日
lastDate = CDate(Trim(Range("D" & i).Value))
'次の送信日を計算
nextDate = lastDate + intervalArray(nextStep)

最終送信日は、Excelのワークシートからセルの値を取得します。

これはフォームが表示されている時に、対象となっているワークシートの場合です。

取得したセルの値を、 CDate() で日付型に変換しています。

日付の計算をするためには、データ型を揃える必要があるからです。

次の送信日は、最終送信日に送信間隔をプラスして計算します。

配列からデータを取り出すには、添え字を指定します。
intervalArray(nextStep)

ポイントは、添え字を変数で指定していることです。

変数の値が変われば、取得できるデータが変わります。

これにより、個々のメールでステップごとに送信間隔を変えることができます。

(5)次の送信日がまだの場合は、メールを作成しないようにしている部分です。

'送信日がまだの場合
If nextDate > Now Then
Exit For
End If

Nowは現在の日時を返します。

次の送信日が現在の日時より大きい場合は、まだメールを送るタイミングではありません。

そこで「Exit For」でFor文を1回抜け出し、次の回へ進みます。

つまり次のメールへ進むということです。

(6)メール送信に成功したら、ワークシート「送信」のステップと最終送信日を更新している部分です。

Private Sub updateData()
省略
End Sub

ポイントは、最大ステップを超える場合、かつ次の送信日が未だの場合は、データを更新しないことです。

条件を満たしているメールだけ、データを更新します。

なぜなら、送信したメールのデータだけを更新しないと、矛盾するからです。

考え方はメールを作成する場合と同じです。(プログラムも同じ)

(7)ステップと最終送信日の更新を行なっている部分です。

'ステップアップ
Range("C" & i).Value = nextStep
'最終送信日を更新
Range("D" & i).Value = Format(Now, "yyyy/mm/dd")

Nowは時刻まで含んでいるので、Format関数で書式を整えています。

(8)上記のSubプロシージャを呼び出している部分です。

'送信に成功したら、ステップと最終送信日を更新する
updateData

またはCall命令を使って、以下のように書いても同じ結果になります。

Call updateData

メールの送信が成功した場合は、ステップと最終更新日を更新する必要があるので、updateData というサブプロシージャを呼び出しています。

(9)一番重要な部分

最大ステップを超える場合、かつ次の送信日が過ぎている場合だけ、メールを送信する部分です。

'開始～終了行番号のメールを作成
For i = startPos To endPos

  '次のステップ
  nextStep = CLng(Trim(Range("C" & i).Value)) + 1

  '最大ステップ数以下の場合
  If nextStep <= maxStep Then

    '最終送信日
    lastDate = CDate(Trim(Range("D" & i).Value))
    '次の送信日を計算
    nextDate = lastDate + intervalArray(nextStep)

    '送信日がまだの場合
    If nextDate > Now Then
      Exit For
    End If

途中省略

  End If

Next i

↓以下のように書くとスッキリすると思うのですが、エラーが出ます。

'開始～終了行番号のメールを作成
For i = startPos To endPos

  '次のステップ
  nextStep = CLng(Trim(Range("C" & i).Value)) + 1

  '最終送信日
  lastDate = CDate(Trim(Range("D" & i).Value))
  '次の送信日を計算
  nextDate = lastDate + intervalArray(nextStep)

  '最大ステップ数以下、かつ送信日がまだの場合
  If (nextStep <= maxStep) And (nextDate > Now) Then

途中省略

  End If

Next i

なぜなら、intervalArray(nextStep)の要素数がオーバーするからです。

フォームで最大ステップに10を入力していた場合、変数 nextStep は 11までカウントアップするので、配列 intervalArray の要素数を超えるためです。

だから解答例のような書き方をしているわけです。

]]>

ステップメールで、送信間隔を設定するプログラムの解答例。

メール送受信入門 — 2010-07-13T07:16:25+09:00

Excelからステップメールを送信するプログラムでは、送信間隔を設定することができます。

これまでに紹介した完成図やヒントを見て、ステップメールのVBAプログラムを改良する課題はできましたか？

出来た人は、プログラミングがかなり上達しています。

出来なかった人も、必ず一度は自分の頭で考えてください。

考えた後にこの解答例を見ることをおすすめします。

自分で考えてみるのと、まったく考えずに解答だけ見るのとでは、理解度が全く違ってくるからです。

今回紹介する解答例は、たくさんある正解の一つに過ぎません。

プログラムには、いろんな書き方があります。

もしあなたが書いた方法で、ステップメールの送信間隔が設定できたなら、それも正解の一つです。

それでは解答例を掲載します。

追加・変更のあったプロシージャのみ掲載しているので、ご注意ください。

変更の無いプロシージャは、そのまま使えるので、ここには掲載していません。

・宣言セクション

Option Explicit

省略
Dim intervalArray() As Integer '送信間隔

・「メール送信」ボタンをクリック時

Private Sub cmd送信_Click()

  'エラーが発生したら処理を行なう
  On Error GoTo Err_Shori

  Dim bobj As Object
  Dim mailto As String
  Dim mailfrom As String
  Dim subj As String
  Dim body As String
  Dim msg As Variant 'メール作成チェック用
  Dim rc As Integer '一括送信チェック用
  Dim i As Long
  Dim tName As String
  Dim eMail As String


  '行番号の値をチェック
  If endPos < startPos Then
    Me.lblMsg = "終了行番号は、開始行番号以上の値を入力してください。"
    'フォーカスを移す
    Me.txtEndPos.SetFocus
    'メール送信ボタン使用不可
    Me.cmd送信.Enabled = False
    Exit Sub
  End If


  '未入力の項目が無いかチェック
  For i = startPos To endPos
    'ワークシートの値を取得
    tName = Trim(Range("A" & i).Value)
    eMail = Trim(Range("B" & i).Value)

    If tName = "" Or eMail = "" Then
      Me.lblMsg = "行番号" & i & "にデータが未入力の項目があります。"
      'フォーカスを移す
      Me.txtEndPos.SetFocus
      'メール送信ボタン使用不可
      Me.cmd送信.Enabled = False
      Exit Sub
    End If

  Next i


  'オブジェクトを作成
  Set bobj = CreateObject("basp21")


  'メールアドレスが有効かチェック
  Dim match As Integer
  Dim target As String
  Dim regstr As String

  regstr = "/^[\w\-+\.]+\@[\w\-+\.]+$/i"

  For i = startPos To endPos
    'ワークシートの値を取得
    eMail = Trim(Range("B" & i).Value)
    target = eMail

    match = bobj.match(regstr, target)

    If match = 0 Then
      Me.lblMsg = "行番号" & i & "のメールアドレスが正しくありません。"
      'メール送信ボタン使用不可
      Me.cmd送信.Enabled = False
      Exit Sub
    End If

  Next i


  '文章を取得して配列にセットする
  Dim textArray() As String '動的配列
  ReDim textArray(1 To maxStep) '要素数を設定

  Dim titleArray() As String
  ReDim titleArray(1 To maxStep)

  ReDim intervalArray(1 To maxStep)

  Dim filePath As String

  For i = 1 To maxStep
    'ワークシートの値を取得
    filePath = Trim(Sheets("文章").Range("B" & i + 1).Value)
    titleArray(i) = Trim(Sheets("文章").Range("C" & i + 1).Value)
    intervalArray(i) = CInt(Trim(Sheets("文章").Range("D" & i + 1).Value))
    '文章を配列にセット
    textArray(i) = readTextFile(filePath)
  Next i


  '送信者
  mailfrom = mSender & vbTab & id & ":" & pass

  '件名取得
  subj = Me.txtSubject

  '本文取得
  body = Me.txtBody

  Dim tmpSubj As String
  Dim tmpBody As String
  Dim files As String
  Dim nextStep As Long
  Dim lastDate As Date
  Dim nextDate As Date

  '開始～終了行番号のメールを作成
  For i = startPos To endPos

    '次のステップ
    nextStep = CLng(Trim(Range("C" & i).Value)) + 1

    '最大ステップ数以下の場合
    If nextStep <= maxStep Then

      '最終送信日
      lastDate = CDate(Trim(Range("D" & i).Value))
      '次の送信日を計算
      nextDate = lastDate + intervalArray(nextStep)

      '送信日がまだの場合
      If nextDate > Now Then
        Exit For
      End If

      'ワークシートの値を取得
      tName = Trim(Range("A" & i).Value)
      eMail = Trim(Range("B" & i).Value)

      '宛先
      mailto = eMail

      '件名を一時変数に代入
      tmpSubj = subj

      '件名に自動挿入
      tmpSubj = Replace(tmpSubj, "[氏名]", tName)
      tmpSubj = Replace(tmpSubj, "[タイトル]", titleArray(nextStep))

      '本文を一時変数に代入
      tmpBody = body

      '本文に自動挿入
      tmpBody = Replace(tmpBody, "[氏名]", tName)
      tmpBody = Replace(tmpBody, "[文章]", textArray(nextStep))

      '添付ファイル
      files = Trim(Range("F" & i).Value)
      files = Replace(files, ";", vbTab)

      'メール作成
      msg = bobj.SendMail(mailq, mailto, mailfrom, tmpSubj, tmpBody, files)

      '作成チェック
      If msg <> "" Then
        MsgBox "行番号" & i & "のメールで作成エラー。" & vbCrLf & msg, vbOKOnly + vbCritical, "作成時エラー"

        '送信用フォルダをクリアする
        If Dir(mailq & "\*.txt") <> "" Then
          Kill mailq & "\*.txt"
        End If

        Exit Sub
      Else
        Me.lblMsg = "行番号" & i & "のメールを作成しました。"
      End If

    End If

  Next i

  Me.lblMsg = "メール送信開始・・・"

  'メール一括送信
  rc = bobj.FlushMail(svname, mailq, logfile)

  '送信チェック
  If rc <= -1 Then
    MsgBox "送信できませんでした。" & vbCrLf & "エラー：" & rc, vbOKOnly + vbCritical, "送信時エラー"
  ElseIf rc = 0 Then
    MsgBox "送信に該当するメールがありませんでした。", vbOKOnly + vbInformation, "情報"
  Else
    '送信に成功したら、ステップと最終送信日を更新する
    updateData
    MsgBox rc & "件のメールを送信しました。", vbOKOnly + vbInformation, "完了"
  End If

  'ラベルをクリア
  Me.lblMsg = ""

Err_Shori_Exit:
  Exit Sub

'ここからエラー処理
Err_Shori:
  MsgBox Err.Description, vbOKOnly + vbCritical, "実行時エラー"
  Resume Err_Shori_Exit
'ここまで

End Sub

・各データの更新

Private Sub updateData()
  'ステップと最終送信日を更新

  Dim i As Long
  Dim nextStep As Long
  Dim lastDate As Date
  Dim nextDate As Date

  For i = startPos To endPos
    '次のステップ
    nextStep = CLng(Trim(Range("C" & i).Value)) + 1

    '最大ステップ数以下の場合
    If nextStep <= maxStep Then

      '最終送信日
      lastDate = CDate(Trim(Range("D" & i).Value))
      '次の送信日を計算
      nextDate = lastDate + intervalArray(nextStep)

      '送信日がまだの場合
      If nextDate > Now Then
        Exit For
      End If

      'ステップアップ
      Range("C" & i).Value = nextStep
      '最終送信日を更新
      Range("D" & i).Value = Format(Now, "yyyy/mm/dd")
    End If

  Next i

End Sub

【動作確認】
プログラミングを行なう時には、動作確認しながらの試行錯誤が欠かせません。

動作確認の手順は、「Step60・課題4 送信間隔を設定する」でも説明しています。

以下に動作確認のポイントだけを書いておきます。

(1)Excelワークシート「送信」の最終送信日の値は、ランダムに入力してかまいません。

でも、必ず今日より前の日付にしてください。＊重要

それと日付の書式(形式)は守って入力します。＊重要

(2)メールの送信が上手くいくと、「ステップ」と「最終送信日」が自動的に更新されることを確認してください。

条件に一致し、送信したメールのデータだけが更新されるはずです。

(3)最大ステップを超える場合、かつ送信日が未だの場合は、メールが送信されないことも確認してください。

ワークシート「送信」のステップに10以上を指定すると、送信されません。
(フォームの最大ステップに10以下を指定した場合)

また最終送信日にステップごとの送信間隔をプラスして、次の送信日を計算し、

もし現在より大きい(未来)だと、まだメールを送信する時期ではないため、送信されません。

つまり条件に一致しないメールは、作成されません。

(4)プログラムの意味については、「Step61・課題4 送信間隔を設定するヒント」を参考にしてください。

いかがでしたか？

あなたの考えたプログラムと合っていましたか。

またはどこが違っていたでしょうか。

上記のプログラムも、プロシージャに分割することで、もっとスッキリ書くことができます。

しかしプログラミング初心者には、上から下に流れるプログラムのほうが理解しやすい(流れを追いやすい)ので、あえてそのままにしています。

余裕のある人は、プロシージャに分割することに挑戦してみるとよいでしょう。

]]>

ステップメールで、送信間隔を設定するプログラムのヒント。

メール送受信入門 — 2010-07-10T07:55:00+09:00

今回は、Excelからステップメールを送信するVBAプログラムの「課題4」のヒントを掲載します。

ステップメールを改良して、送信間隔を設定できるプログラムを作成します。

課題4の内容や動作確認の方法は、「Step60・課題4 送信間隔を設定する」をご覧ください。

課題の説明だけで、プログラミングできることが理想的です。

でもプログラミング初心者には、まだまだ難しい部分もあると思います。

そこでいくつかヒントを出しておきます。

以下のヒントを見ただけで、プログラミングができたら、とりあえず課題は合格です。

(1)新しい変数名
送信間隔　intervalArray()　Integer型の配列

どこで変数を宣言したほうがよいのか、考えてください。

ヒントは変数の有効範囲です。

そのプロシージャ内だけで使う場合と、複数のプロシージャで共通して使う場合は、宣言する場所が異なります。

また配列の変数は、どのように宣言するのか、復習も兼ねています。

ステップメールのタイトルや文章を代入した配列を思い出してください。要領は同じです。

(2)メールの送信間隔を取得する配列の要素数を変更します。

ReDim intervalArray(1 To maxStep)

配列は1から始まり、最大ステップ数までになっているのがポイントです。

理由は、配列とステップの番号を揃えるためです。

このプログラムをどこに書けばいいのか、考えてみてください。

(3)メールの送信間隔は、配列を使って、Excelのワークシートから、あらかじめ取得しておきます。

intervalArray(i) = CInt(Trim(Sheets("文章").Range("D" & i + 1).Value))

このプログラムをどこに書けばいいのか、考えてみてください。

ヒントは、繰り返しの制御文の中です。

タイトルや文章の場合を思い出してください。要領は同じです。

(4)メールの最終送信日を取得し、次の送信日を計算します。

'最終送信日
lastDate = CDate(Trim(Range("D" & i).Value))
'次の送信日を計算
nextDate = lastDate + intervalArray(nextStep)

CDate()は、引数を日付型に変換するVBAの関数です。

日付の計算をするためには、データ型を揃える必要があるからです。

(5)次の送信日がまだの場合は、メールを作成しないようにします。

'送信日がまだの場合
If nextDate > Now Then
Exit For
End If

Nowは現在の日時を返します。

次の送信日が現在の日時より大きい場合は、まだメールを送るタイミングではありません。

そこで「Exit For」でFor文を1回抜け出し、次の回へ進みます。

つまり次のメールへ進むということです。

これをどこに組み込めばよいのか、考えてみてください。

(6)メール送信に成功したら、ワークシート「送信」のステップと最終送信日を更新します。

前回に「updateStep」というSubプロシージャを作りましたが、それを改良します。

ただし今回は、ステップと最終送信日を同時に更新するため、Subプロシージャ名が適切ではなくなります。

そのため「updateData」に変更しましょう。

updateStep → updateData

Private Sub updateData()
省略
End Sub

このSubプロシージャの中身を考えて、完成させてください。

ヒントは、最大ステップを超える場合、かつ送信日が未だの場合は、データを更新しないことです。

なぜなら、送信したメールのデータだけを更新しないと、矛盾するからです。

考え方はメールを作成する場合と同じです。(プログラムも同じ)

(7)ステップと最終送信日の更新は、次のように行ないます。

'ステップアップ
Range("C" & i).Value = nextStep
'最終送信日を更新
Range("D" & i).Value = Format(Now, "yyyy/mm/dd")

Nowは時刻まで含んでいるので、Format関数で書式を整えています。

このプログラムを updateData プロシージャの中に組み込んでください。

(8)上記のSubプロシージャを呼び出して使う時には、以下のようにします。

updateData

またはCall命令を使って、以下のように書いても同じ結果になります。

Call updateData

これをどこで呼び出したらよいのか、考えてください。

updateStep → updateData

ヒントは、メールの送信が上手くいった場合にだけ、呼び出すということです。

以上のヒントを参考にして、課題プログラムの作成に挑戦してみてください。

ヒントと言っても、ほとんど答えを書いているようなものですね。

どうですか？

送信間隔を指定できるステップメールは、上手くプログラミングできたでしょうか？

]]>

ステップメールで、送信間隔を設定できるようにするプログラム。

メール送受信入門 — 2010-01-24T07:50:24+09:00

Excelからステップメールを送信するVBAプログラムの仕上げとして、送信間隔を設定できるように、プログラムをカスタマイズ(改良)してみましょう。

通常、ステップメールでは、次のステップを送信するまでの送信間隔(1日後、3日後、7日後など)を設定できるものがあります。

そこで今回の課題では、以下のようなステップメールを送信できる機能を実現します。

まずは完成図を見て、イメージを掴んでください。

【完成図】
(1)ワークシート「送信」のD列に、「最終送信日」を記録できるようにします。

最終送信日とは、前回にステップメールを送信した日付のことです。

ステップが 0 の場合は、新しい読者なので、まだメールは未送信です。その時は登録日の日付を入力しておきます。

＊日付は空白にはしないでください。
＊日付として正しい形式で入力します。(半角で)

日付の値は、ランダムに入力してかまいません。でも、必ず今日より前の日付にしてください。

(2)ステップメールの送信が成功すると、D列の最終送信日を、更新するようにします。
自動的に送信日の日付が、入力されるようにしてください。

(3)ワークシート「文章」では、D列に次のステップメールを送るまでの「間隔(日)」を指定できるようにします。

＊数値は、半角で入力してください。
＊step1は新規の読者なので、間隔は0にします。(すぐに送るため)

間隔の値は、ランダムに入力してかまいません。

例えば上の図では、step1とstep2の間には、1日あることになります。

また、step4はstep3を送ってから、3日後に送信するという意味です。

(4)動作確認について
今回の課題の動作確認の方法は、これまでと変わりません。

ワークシート「送信」に切り替えると、ユーザーフォーム「frm送信」が自動的に表示されます。

あとはテキストボックスに入力して、メールを一括送信します。

送信フォームの件名と本文に入力する文字列を掲載しておきます。動作確認の際にご利用ください。

・件名

[氏名]様　[タイトル]

・本文

[氏名]様

こんにちは。○○です。
本日はメールマガジンをお届けします。

[氏名]様のお役に立てれば幸いです。

[文章]

最後までお読みいただき、ありがとうございました。
株式会社○○

既に最大ステップに達している人には、これ以上メールが配信されないのは、前回までと同じです。

これまでとの違いは、ステップごとに間隔(日)を設定しているので、条件を満たしていない場合は、メールが送信されないことです。

つまり、最大ステップに達していない、かつ日付の間隔を満たしている時だけ、ステップメールが送信されます。

そして最後に、ワークシート「送信」のD列の最終送信日が、自動的に更新されていることを確認してください。

もちろん今回送信した人だけ、更新されていなければなりません。

(5)メーラーで受信してみる
ステップメールの送信が上手くいったかどうかは、送信したメールを Outlook Express のようなメーラーで受信して確認します。

・条件に一致しているメールは、ちゃんと届いていますか？
・本来は送信されないはずのメールが届いていませんか？

【課題の手順】
今回の課題は、前回までに作成した「ステップメール.xls」をカスタマイズして行ないます。ついでにステップメールの復習を兼ねています。

課題は、以下の順番で行なってください。
・「ステップメール.xls」を開く　＊マクロを有効にする
・VBEを起動する　「Altキー」＋「F11キー」
・プログラムを一部変更、追加する
・動作確認

以上の図と説明を見ただけで、ステップメールをカスタマイズできれば、かなりプログラミングが上達しています。

まずは自力で挑戦してみてください。もし出来なくても、自分の頭で考えてみることが大切です。

「日付をどう扱うか」というのがポイントです。

次回にヒントを掲載します。

【補足】
今回の課題では、完全には自動化していません。

ユーザーが送信作業を行なう時に、日付を計算して、条件を満たしていれば送信するという、シンプルな仕組みにします。

したがって、ユーザーが毎日一度は、「メール送信」ボタンをクリックすることが、前提となっています。

ユーザーが送信作業を怠けると、必ずしも設定した間隔で送信されるとは限りません。少し遅れることもあります。

完全に自動化するには、タイマーなどの機能を追加すれば可能です。

毎日決まった時間に、自動的に「メール送信」ボタンをクリックするように、プログラミングするだけです。

でもここまでやると、課題としては難しくなるので、今回は省きました。

]]>

Excelでステップメールを送信するプログラムの解説。

メール送受信入門 — 2010-01-22T07:44:00+09:00

今回は、Excelからステップメールを送信するためのVBAプログラムについて、詳しく解説します。

実は既に以下のステップで、ほとんど説明済みです。
・Step55で完成図
・Step56、Step57でプログラムのヒント
・Step57で解答例

そこで今回は、大事なポイントだけを、解説することにします。

また以前のステップと重なっている説明もあるのですが、ご了承ください。繰り返し書いているということは、それだけ重要な部分です。

(1)最大ステップを代入するための変数を宣言している部分です。

Dim maxStep As Long

変数の有効範囲に気をつけてください。

この変数は、複数のプロシージャで共通して使います。したがって宣言セクションで、変数の宣言をしています。

(2)文章を取得して配列にセットする部分については、Step57で説明済みです。
Dim textArray() As String からの部分

この部分が、ステップメールで一番重要なところです。

文章とタイトルは、配列を使って、あらかじめ取得しておきます。

ただし、メール送信フォームを開いたからといって、必ずしも送信するとは限りません。

そこでユーザーが、「メール送信」ボタンをクリックした時に取得しています。

この部分は、サブプロシージャとして分けたほうが、スッキリするかもしれません。

(3)ステップメールでも、ユーザーフォームから、件名と本文を取得します。

'件名取得
subj = Me.txtSubject
'本文取得
body = Me.txtBody

これらは、ステップメールで、どのメールにも共通する文字になります。

(4)件名と本文を、一時的に格納するため、変数を宣言している部分です。

Dim tmpSubj As String
Dim tmpBody As String

ステップメールでは、個々のメールの内容が異なるため、元になる変数(subj、body)を直接書き換えてしまうと、不都合があります。

そのため、変数の内容をコピーするための一時変数を準備しています。

(5)次のステップを代入する変数を宣言している部分です。

Dim nextStep As Long

この変数の有効範囲は、宣言したプロシージャ内だけです。

(6)次のステップを計算している部分です。

nextStep = CLng(Trim(Range("C" & i).Value)) + 1

次のステップは、現在のステップに1を加算するだけです。

現在のステップは、Excelのワークシートからセルの値を取得します。

これはフォームが表示されている時に、対象となっているワークシートの場合です。

変数 i には、行番号が入っています。iが変化することで、異なる行の値を取得できます。

Trim関数を使っているのは、前後の空白を取り除くためです。

あとは、取得したセルの値を、念のため CLng で長整数型に変換してから、1をプラスしています。

(7)次のステップが、最大ステップ数以下の場合だけ、処理を行なうようにしている部分です。

If nextStep <= maxStep Then
省略
End If

最大ステップを超える場合は、メールを作成しないようにするための処理です。

(8)件名に値を自動挿入している部分です。

tmpSubj = subj
tmpSubj = Replace(tmpSubj, "[氏名]", tName)
tmpSubj = Replace(tmpSubj, "[タイトル]", titleArray(nextStep))

元の変数の値(subj)は変えずに置換したいので、一時変数(tmpSubj)に代入しています。

自動挿入するためには、Replace関数を使って置換します。
＊置換するのは tmpSubj のほうです。

件名では、挿入タグ(検索文字列)に、以下のものが使えます。
[氏名]、[タイトル]

配列からデータを取り出すには、添え字を指定します。
titleArray(nextStep)

ポイントは、添え字を変数で指定することです。変数の値が変われば、取得できるデータが変わります。

(9)本文に値を自動挿入している部分です。

tmpBody = body
tmpBody = Replace(tmpBody, "[氏名]", tName)
tmpBody = Replace(tmpBody, "[文章]", textArray(nextStep))

要領は件名と同じです。

本文では、挿入タグ(検索文字列)に、以下のものが使えます。
[氏名]、[文章]

(10)個々のメールを作成している部分です。

msg = bobj.SendMail(mailq, mailto, mailfrom, tmpSubj, tmpBody, files)

件名と本文の引数には、一時変数(tmpSubj、tmpBody)を使っている点に注目してください。

これにより、個々のメールで内容を変えることができます。

元の変数(subj、body)を使うと、全部同じメールになるので注意してください。それに挿入タグ(検索文字列)も、残ったままになるはずです。

(11)送信チェックを行なっているプログラムを変更しました。

'送信チェック
If rc <= -1 Then
  MsgBox "送信できませんでした。" & vbCrLf & "エラー：" & rc, vbOKOnly + vbCritical, "送信時エラー"
ElseIf rc = 0 Then
  MsgBox "送信に該当するメールがありませんでした。", vbOKOnly + vbInformation, "情報"
Else
  '送信に成功したら、ステップアップする
  updateStep
  MsgBox rc & "件のメールを送信しました。", vbOKOnly + vbInformation, "完了"
End If

ステップメールでは、必ずしも該当するメールがあるとは限りません。

例えば、全ての人が既に最大ステップに達している場合も考えられます。

そのままでは、送信するメールが無い時に、「送信時エラー」が表示されてしまうので、少しだけ変更しました。

該当するメールが無い場合は、変数rc に「0」が代入されています。それを利用して、メッセージを表示することにしました。
ElseIf rc = 0 Then の部分

また、送信が成功した場合は、ステップアップする必要があるので、updateStep というサブプロシージャを呼び出しています。

Call命令を使って、以下のように書いても同じ結果になります。
Call updateStep

(12)最大ステップを更新した時のイベントプロシージャです。

Private Sub txtMaxStep_Exit(ByVal Cancel As MSForms.ReturnBoolean)
省略
End Sub

ユーザーフォームで、最大ステップに入力した値をチェックするため、イベントプロシージャを新たに作成しました。

行番号のテキストボックスと、ほとんど同じ処理です。少し書き換えただけです。

(13)フォームを初期化時のイベントプロシージャに、プログラムを追加しています。

Private Sub UserForm_Initialize()
省略
Me.txtMaxStep = 10
省略
maxStep = 10
省略

最大ステップのテキストボックス(txtMaxStep)と変数(maxStep)に、初期値として「10」を代入しています。

変数maxStepにも初期値を代入するのは、ユーザーフォームを開いた時に、テキストボックスの値を変更せずに送信することもあるからです。

maxStepの値は、テキストボックスを更新したタイミングで代入される仕組みにしているので、テキストボックスを操作しない場合は、変数の値が空になります。

それを防ぐための処理です。

(14)ステップを更新するためのSubプロシージャを、新しく作成しました。

Private Sub updateStep()
  'ステップ更新

  Dim i As Long
  Dim nextStep As Long

  For i = startPos To endPos
    '次のステップ
    nextStep = CLng(Trim(Range("C" & i).Value)) + 1

    '最大ステップ数以下の場合
    If nextStep <= maxStep Then
      'ステップアップ
      Range("C" & i).Value = nextStep
    End If

  Next i

End Sub

メール送信が成功したら、ワークシート「送信」のステップを、更新する必要があります。

ポイントは、最大ステップを超える場合は、ステップアップしないことです。つまり最大ステップ数以下の場合だけステップアップします。
If nextStep <= maxStep Then の部分

このように、処理をSubプロシージャに分けることで、本体のプログラムがシンプルになります。

]]>

ステップメールを送信するプログラムの解答例。

メール送受信入門 — 2009-10-24T08:09:31+09:00

Excelからステップメールを送信することができます。

完成図やヒントを見て、ステップメールのVBAプログラムを作成する課題はできましたか？

出来た人は、プログラミングの実力がアップしています。

出来なかった人も、一度は自分の頭で考えてから解答例を見ることをおすすめします。

考えずに解答だけ見ると、理解度が全く違ってくるからです。

今回紹介する解答例は、正解の一つに過ぎません。プログラムにはいろんな書き方があるので、もしあなたが書いた方法で、ステップメールが送信できているなら、それも正解の一つです。

それでは解答例を掲載します。

追加・変更のあったプロシージャのみ掲載しているので、ご注意ください。変更の無いプロシージャはそのまま使えるので、ここには掲載していません。

Option Explicit

Dim svname As String
Dim id As String
Dim pass As String
Dim mSender As String '送信者
Dim mailq As String 'メールキュー
Dim logfile As String 'ログファイル
Dim startPos As Long '開始行番号
Dim endPos As Long '終了行番号
Dim maxStep As Long '最大ステップ

Private Sub cmd送信_Click()

  'エラーが発生したら処理を行なう
  On Error GoTo Err_Shori

  Dim bobj As Object
  Dim mailto As String
  Dim mailfrom As String
  Dim subj As String
  Dim body As String
  Dim msg As Variant 'メール作成チェック用
  Dim rc As Integer '一括送信チェック用
  Dim i As Long
  Dim tName As String
  Dim eMail As String


  '行番号の値をチェック
  If endPos < startPos Then
    Me.lblMsg = "終了行番号は、開始行番号以上の値を入力してください。"
    'フォーカスを移す
    Me.txtEndPos.SetFocus
    'メール送信ボタン使用不可
    Me.cmd送信.Enabled = False
    Exit Sub
  End If


  '未入力の項目が無いかチェック
  For i = startPos To endPos
    'ワークシートの値を取得
    tName = Trim(Range("A" & i).Value)
    eMail = Trim(Range("B" & i).Value)

    If tName = "" Or eMail = "" Then
      Me.lblMsg = "行番号" & i & "にデータが未入力の項目があります。"
      'フォーカスを移す
      Me.txtEndPos.SetFocus
      'メール送信ボタン使用不可
      Me.cmd送信.Enabled = False
      Exit Sub
    End If

  Next i


  'オブジェクトを作成
  Set bobj = CreateObject("basp21")


  'メールアドレスが有効かチェック
  Dim match As Integer
  Dim target As String
  Dim regstr As String

  regstr = "/^[\w\-+\.]+\@[\w\-+\.]+$/i"

  For i = startPos To endPos
    'ワークシートの値を取得
    eMail = Trim(Range("B" & i).Value)
    target = eMail

    match = bobj.match(regstr, target)

    If match = 0 Then
      Me.lblMsg = "行番号" & i & "のメールアドレスが正しくありません。"
      'メール送信ボタン使用不可
      Me.cmd送信.Enabled = False
      Exit Sub
    End If

  Next i


  '文章を取得して配列にセットする
  Dim textArray() As String '動的配列
  ReDim textArray(1 To maxStep) '要素数を設定

  Dim titleArray() As String
  ReDim titleArray(1 To maxStep)

  Dim filePath As String

  For i = 1 To maxStep
    'ワークシートの値を取得
    filePath = Trim(Sheets("文章").Range("B" & i + 1).Value)
    titleArray(i) = Trim(Sheets("文章").Range("C" & i + 1).Value)
    '文章を配列にセット
    textArray(i) = readTextFile(filePath)
  Next i


  '送信者
  mailfrom = mSender & vbTab & id & ":" & pass

  '件名取得
  subj = Me.txtSubject

  '本文取得
  body = Me.txtBody

  Dim tmpSubj As String
  Dim tmpBody As String
  Dim files As String
  Dim nextStep As Long

  '開始～終了行番号のメールを作成
  For i = startPos To endPos

    '次のステップ
    nextStep = CLng(Trim(Range("C" & i).Value)) + 1

    '最大ステップ数以下の場合
    If nextStep <= maxStep Then

      'ワークシートの値を取得
      tName = Trim(Range("A" & i).Value)
      eMail = Trim(Range("B" & i).Value)

      '宛先
      mailto = eMail

      '件名を一時変数に代入
      tmpSubj = subj

      '件名に自動挿入
      tmpSubj = Replace(tmpSubj, "[氏名]", tName)
      tmpSubj = Replace(tmpSubj, "[タイトル]", titleArray(nextStep))

      '本文を一時変数に代入
      tmpBody = body

      '本文に自動挿入
      tmpBody = Replace(tmpBody, "[氏名]", tName)
      tmpBody = Replace(tmpBody, "[文章]", textArray(nextStep))

      '添付ファイル
      files = Trim(Range("F" & i).Value)
      files = Replace(files, ";", vbTab)

      'メール作成
      msg = bobj.SendMail(mailq, mailto, mailfrom, tmpSubj, tmpBody, files)

      '作成チェック
      If msg <> "" Then
        MsgBox "行番号" & i & "のメールで作成エラー。" & vbCrLf & msg, vbOKOnly + vbCritical, "作成時エラー"

        '送信用フォルダをクリアする
        If Dir(mailq & "\*.txt") <> "" Then
          Kill mailq & "\*.txt"
        End If

        Exit Sub
      Else
        Me.lblMsg = "行番号" & i & "のメールを作成しました。"
      End If

    End If

  Next i

  Me.lblMsg = "メール送信開始・・・"

  'メール一括送信
  rc = bobj.FlushMail(svname, mailq, logfile)

  '送信チェック
  If rc <= -1 Then
    MsgBox "送信できませんでした。" & vbCrLf & "エラー：" & rc, vbOKOnly + vbCritical, "送信時エラー"
  ElseIf rc = 0 Then
    MsgBox "送信に該当するメールがありませんでした。", vbOKOnly + vbInformation, "情報"
  Else
    '送信に成功したら、ステップアップする
    updateStep
    MsgBox rc & "件のメールを送信しました。", vbOKOnly + vbInformation, "完了"
  End If

  'ラベルをクリア
  Me.lblMsg = ""

Err_Shori_Exit:
  Exit Sub

'ここからエラー処理
Err_Shori:
  MsgBox Err.Description, vbOKOnly + vbCritical, "実行時エラー"
  Resume Err_Shori_Exit
'ここまで

End Sub

Private Sub txtMaxStep_Exit(ByVal Cancel As MSForms.ReturnBoolean)
  'エラーが発生したら処理を行なう
  On Error GoTo Err_Shori

  'メール送信ボタン使用不可
  Me.cmd送信.Enabled = False

  '最大ステップが空白の時の処理
  If Me.txtMaxStep = "" Then
    Me.lblMsg = "最大ステップを入力してください。"
    Cancel = True
    Exit Sub
  End If

  '最大ステップを取得
  maxStep = CLng(Me.txtMaxStep)

  '最大ステップが1未満の時の処理
  If maxStep < 1 Then
    Me.lblMsg = "最大ステップは、1以上の数値を入力してください。"
    Cancel = True
    Exit Sub
  End If

  'ラベルをクリア
  Me.lblMsg = ""
  'メール送信ボタン使用可
  Me.cmd送信.Enabled = True

Err_Shori_Exit:
  Exit Sub

'ここからエラー処理
Err_Shori:
  MsgBox Err.Description, vbOKOnly + vbCritical, "実行時エラー"
  Cancel = True
  Resume Err_Shori_Exit
'ここまで

End Sub

Private Sub UserForm_Initialize()
  'メール送信ボタン使用不可
  Me.cmd送信.Enabled = False

  '初期値
  Me.txtStartPos = 2
  Me.txtEndPos = 2
  Me.txtMaxStep = 10
  startPos = 2
  endPos = 2
  maxStep = 10

  '送信者
  mSender = Trim(Sheets("設定").Range("B1").Value)

  'SMTPサーバー
  svname = Trim(Sheets("設定").Range("B2").Value)

  '送信ID
  id = Trim(Sheets("設定").Range("B3").Value)

  '送信パスワード
  pass = Trim(Sheets("設定").Range("B4").Value)

  'メールキュー
  mailq = "C:\mailPG\Send"

  'ログファイル
  logfile = "C:\mailPG\logfile.txt"
End Sub

Private Sub updateStep()
  'ステップ更新

  Dim i As Long
  Dim nextStep As Long

  For i = startPos To endPos
    '次のステップ
    nextStep = CLng(Trim(Range("C" & i).Value)) + 1

    '最大ステップ数以下の場合
    If nextStep <= maxStep Then
      'ステップアップ
      Range("C" & i).Value = nextStep
    End If

  Next i

End Sub

【動作確認】
プログラミングを行なう時には、動作確認しながらの試行錯誤が欠かせません。

(1)動作確認の手順は、前回の Step55・課題3 ステップメールを送信するの「完成図」と同じ要領です。

(2)メールの送信が上手くいくと、ステップが自動的に更新されることも確認してください。

また、最大ステップを超えるメールは送信されないことも確認してください。ワークシート「送信」のステップに10以上を指定すると、送信されません。

(3)プログラムについては、Step56、Step57のヒントを参考にしてください。

【ワンポイント】
今回はステップメールを送信する前に、タイトルと文章をあらかじめ配列に格納しました。

この方法は、送信するメール数に対し、文章数が少ない時に有効です。あらかじめデータを用意しておくことで、処理が速くなります。(ただしメモリーは消費する)

逆に文章数のほうが多く、メール数が少ない場合には、使わない文章まで読み込んでおくと無駄になります。

そのような場合には、メールを作成する時に、必要な文章だけ読み込むという手もあります。

どちらの方法が良いのかは、システムの使い方によって変わります。

]]>

ステップメールの文章を格納するために、配列を使ったプログラムの解説。

メール送受信入門 — 2009-10-23T08:07:03+09:00

今回は、Excelからステップメールを送信するために、タイトルや文章を配列に格納する部分のVBAプログラムについて解説します。

配列とは、同じ変数名でデータを扱いたい時に便利な仕組みです。

配列と繰り返しの制御文を組み合わせることで、プログラムをシンプルに書くことができます。

例えば変数が100個必要な場合をイメージしてみてください。

それぞれの変数名を100も考えるのは大変ですよね。それに100個の変数を初期化したり、値を代入する処理も大変です。

Dim a, b, c ・・・ As Integer
a = 0
b = 1
c = 2
・・・
Debug.Print a
Debug.Print b
Debug.Print c
・・・

そんな時は、配列を使えば変数名は1つで済むし、処理も簡単になります。

・最も簡単な例

Dim a(99) As Integer
Dim i As Integer

For i = 0 To 99
a(i) = i
Debug.Print a(i)
Next i

配列を宣言する時には、配列名の後に要素数を指定し、配列のデータ型を書きます。
例　Dim a(99) As Integer
これは a という変数を 0～99 まで用意し、そのデータ型は整数型であるという宣言です。

配列は、通常「0」から始まるので、注意してください。
a(99)　0～99の100個になる
a(100)　0～100の101個になる

＊99のような値を要素数という。

要素数には、リテラルの数値(5や10など)か、定数を指定できます。

ここで大事なことですが、要素数に変数を指定することはできないので、気をつけてください。

また、配列に格納された値を利用するには、配列名に添字を指定します。
例　a(0)、a(1)・・・a(99)

＊0のような値を添字という。

以上までが、配列を使う処理の基本です。

それでは上記の基本を踏まえて、タイトルや文章を配列に格納する部分のVBAプログラムについて詳しく説明します。

・今回使うプログラム

'文章を取得して配列にセットする
Dim textArray() As String '動的配列
ReDim textArray(1 To maxStep) '要素数を設定

Dim titleArray() As String
ReDim titleArray(1 To maxStep)

Dim filePath As String

For i = 1 To maxStep
  'ワークシートの値を取得
  filePath = Trim(Sheets("文章").Range("B" & i + 1).Value)
  titleArray(i) = Trim(Sheets("文章").Range("C" & i + 1).Value)
  '文章を配列にセット
  textArray(i) = readTextFile(filePath)
Next i

通常、配列の添字は 0 から始まります。

でもメールのステップは「1」から始まります。また「1～最大ステップ」の範囲で要素数が変化します。

したがって配列を宣言する時の要素数には、変数を使いたいところです。しかし要素数には変数が使えません。

そこで、まずは要素数を指定しないで宣言しておいて、
Dim textArray() As String

あらためて ReDim を使って「動的配列」として、配列の要素数を設定し直しています。
ReDim textArray(1 To maxStep)

これを「部分範囲指定配列」と言います。

この方法だと、配列の要素数に変数が利用できます。

また配列の添字と、メールのステップ番号が一致できるメリットもあります。

もし通常のように添え字を 0 から始める場合は、プログラムで加算などの調整をする必要があります。

できれば配列の番号とステップの番号を一致させていたほうがわかりやすいので、このような書き方にしました。

ワークシート「文章」からデータを取得する時に、「+1」しているのは、1行目が見出しだからです。これも番号を一致させるための工夫です。

例　Sheets("文章").Range("B" & i + 1).Value

他のワークシートを参照する場合は、シート名から始める必要があります。

メール本文に挿入する文章を取得し、配列に保存しておくためには、まずファイル名を取得します。

filePath = Trim(Sheets("文章").Range("B" & i + 1).Value)

そしてユーザー定義関数として作成した readTextFile を使い文章を取得します。

textArray(i) = readTextFile(filePath)

この関数は、引数としてファイル名をフルパスで指定すると、テキストファイルからデータを読み込み、文字列として返します。

返って来る値を「戻り値」といいます。

その戻り値を、文字列型の配列で受け取っているわけです。配列の添字(i)が変化することで、複数の文章を格納しておくことができます。

タイトルの場合は、もっと単純で、ワークシートから取得した値を、配列に直接格納しているだけです。

titleArray(i) = Trim(Sheets("文章").Range("C" & i + 1).Value)

実は今回作成した、タイトルや文章を配列に格納する部分のVBAプログラムは、Functionプロシージャ(関数プロシージャ)として、分離することもできます。

そのほうが、メインのプログラムがシンプルになります。

でもプログラムの流れを追いやすいように、あえてそのまま書くことにします。

余裕のある人は、Functionプロシージャの作成に挑戦してみてください。

]]>

ステップメールを送信する課題プログラムのヒント。

メール送受信入門 — 2009-10-22T08:03:35+09:00

今回は、Excelからステップメールを送信するVBAプログラムのヒントを掲載します。

できるだけシステムの完成図や動作確認のイメージから、プログラミングできることが理想的です。

でも初心者には少し難しい部分もあるので、いくつかヒントを出しておきます。

これらのヒントを見ただけで、プログラミングができたら、とりあえず課題は合格です。

(1)新しい変数名
最大ステップ　maxStep　Long型
次のステップ　nextStep　Long型

それぞれどこで変数を宣言したほうがよいのか、考えてください。

ヒントは変数の有効範囲です。そのプロシージャ内だけで使う場合と、複数のプロシージャで共通して使う場合は、宣言する場所が異なります。

(2)フォームを初期化時のイベントプロシージャにプログラムを追加します。

最大ステップのテキストボックス(txtMaxStep)と変数(maxStep)に、初期値として「10」を代入します。

Private Sub UserForm_Initialize()
省略
End Sub

どのように書けばよいのか考えてください。このプロシージャ内にヒントがあります。

(3)最大ステップに入力した値をチェックするため、イベントプロシージャを新たに作成します。

Private Sub txtMaxStep_Exit(ByVal Cancel As MSForms.ReturnBoolean)
省略
End Sub

ヒントは、行番号のテキストボックスと同じ要領です。少し書き換えるだけで済みます。

またイベントプロシージャは、必ずコンボボックスから選択して作成してください。

(4)Excelのワークシートからセルの値を取得するには、以下のようにします。

Range("C" & i).Value

これはフォームが表示されている時に、対象となっているワークシートの場合です。

変数 i には、行番号が入っています。iが変化することで、異なる行の値を取得できます。

(5)文章とタイトルは、配列を使って、あらかじめ取得しておきます。

この部分がステップメールで一番重要なところです。少し難しいので、プログラムを掲載しておきます。

このプログラムをどこに書けばいいのか、考えてみてください。

ヒントは、メール送信フォームを開いたからといって、必ずしも送信するとは限らないことです。

上記の配列を使ったプログラムについては、次回に詳しく解説します。とりあえず今回は、そのまま使ってください。

(6)次のステップは、現在のステップに1を加算するだけです。

nextStep = CLng(Trim(Range("C" & i).Value)) + 1

(7)次のステップが、最大ステップ数以下の場合だけ、処理を行なうようにします。

If nextStep <= maxStep Then
省略
End If

最大ステップを超える場合は、メールを作成しないようにするための処理です。

これをどこに組み込めばよいのか、考えてみてください。

(8)挿入タグ(検索文字列)は、次のようにしてください。
[氏名]、[タイトル]、[文章]

自動挿入するためには、Replace関数を使って置換します。

(9)通常、配列からデータを取り出すには、添え字を指定します。
例　titleArray(1)、titleArray(2)、titleArray(3)・・・
例　textArray(1)、textArray(2)、textArray(3)・・・

番号が変われば、取得できるデータが変わります。このように()「括弧」で囲まれた値を添え字といいます。

ヒントは、添え字を変数で指定することです。

(10)ステップメールでは、必ずしも該当するメールがあるとは限りません。

例えば、全ての人が既に最大ステップに達している場合も考えられます。

ところが今のままでは、送信するメールが無い時に、「送信時エラー」が表示されてしまいます。

したがって送信チェックを行なっているプログラムを変更する必要があります。

If rc <= 0 Then
MsgBox "送信できませんでした。" & vbCrLf & "エラー：" & rc, vbOKOnly + vbCritical, "送信時エラー"
Else
MsgBox rc & "件のメールを送信しました。", vbOKOnly + vbInformation, "完了"
End If

ヒントは、該当するメールが無い場合は、変数rc に「0」が代入されています。

(11)メール送信が成功したら、ワークシート「送信」のステップを、更新する必要があります。

そこでステップを更新するためのSubプロシージャを、新しく作成します。

Private Sub updateStep()
省略
End Sub

このSubプロシージャの中身を考えて、完成させてください。

ヒントは、最大ステップを超える場合は、ステップアップしないことです。

(12)上記のSubプロシージャを呼び出して使う時には、以下のようにします。

updateStep

またはCall命令を使って、以下のように書いても同じ結果になります。

Call updateStep

これをどこで呼び出したらよいのか、考えてください。

ヒントは、メールの送信が上手くいった場合にだけ、呼び出すということです。

このように、処理をSubプロシージャに分けることで、本体のプログラムがシンプルになります。

以上のヒントを参考にして、プログラムの作成に挑戦してみてください。

どうですか？ステップメールは上手くプログラミングできたでしょうか？

どうしてもわからない場合は、メール送信の基礎からもう一度復習して、再度チャレンジしてみるとよいでしょう。

]]>

Excelでステップメールを送信するプログラム。

メール送受信入門 — 2009-10-20T08:02:36+09:00

いよいよExcelからステップメールを送信するVBAプログラムを作成してみましょう。

今回の課題では、以下のようなステップメールを送信できる機能を実現します。

【完成図】
(1)ワークシート「送信」のC列で、ステップを指定できるようにします。

ステップとは、今どの段階までメールを送信済みか表します。
・0の場合は新しい読者　まだメールは未送信
・1の場合は、1回目のメールは送信済み

ステップの数値は、ランダムに入力してかまいません。

でも、あらかじめ準備した文章のテキストファイル数と一致させる必要があるので、0～10 の範囲内で指定してください。

また実際にステップメールを送信する時には、ワークシート「送信」のC列に「+1」した値を使います。

ステップに入力されているのは、「送信済み」の値なので、新しいメールは次の値になるからです。

(2)ワークシート「文章」では、メールの本文中に挿入するテキストファイル名(B列)と、メールの件名に挿入するタイトル(C列)を指定できるようにします。

＊タイトルは、全て入力してください。
＊テキストファイル名は、フルパスで指定します。

フルパスで指定することで、ファイルはどこに保存しても添付できるメリットがあります。

(3)ワークシート「送信」に切り替えると、ユーザーフォーム「frm送信」が自動的に表示されます。

以下のように入力して、メールを一括送信できるようにします。

・行番号と最大ステップには、初期値が入力される。
・送信するメールの範囲を指定できるようにする。
・メールは1通でも送れるようにする。
・最大ステップを指定できるようにする。
・件名に、氏名とタイトルを挿入できるようにする。
・本文に、氏名と文章を挿入できるようにする。
・文章はステップによって自動的に変わる。
・添付ファイルの機能は、そのまま残す。

最大ステップを指定する理由は、メールを送信する度にワークシート「送信」のステップをカウントアップしますが、用意したファイル数の10を超えないように、プログラム側で制御するためです。

例えば、ステップが既に10の人には、これ以上メールが配信されないようにします。

送信フォームの件名と本文に入力する文字列を掲載しておきます。動作確認の際にご利用ください。

・件名

[氏名]様　[タイトル]

・本文

メール本文のテキストボックスを詳しく見てみましょう。

(4)挿入タグを使い、本文に氏名を自動的に挿入できるようにします。

＊同じ挿入タグは、何回でも使えます。

(5)どのステップメールでも共通する部分(ヘッダーやフッター)は、ユーザーが自由に入力できるようにします。

(6)挿入タグを使い、ステップごとに指定したテキストファイルを読み込んで、メール本文に「文章」を挿入できるようにします。

＊ここがステップメールで一番大事な部分です。

以上がメール送信に関する部分です。

次は送信されたメールが、どのように届くか見てみましょう。
以下は Outlook Express のようなメーラーで受信した場合です。

(7)メールの件名に、氏名やタイトルが自動的に挿入されています。

＊もし添付ファイルを指定してあれば、添付されます。

各メールを開いて、中を詳しく確認してみます。

(8)メール本文に氏名が自動的に挿入されています。

(9)共通するヘッダー部分です。

(10)テキストファイルから読み込んだ文章が、メール本文に挿入されています。

宛先のステップごとにメールの本文がちゃんと変わります。

(11)共通するフッター部分もちゃんとあります。

(12)正常に送信が完了すると、ワークシート「送信」のステップ(C列)が、自動的にカウントアップします。

ただし、最大ステップを超えないようにします。

【課題の手順】
プログラミングの手順は、「メール送受信.xls」の場合とほとんど同じです。したがってメール送信の復習を兼ねています。

課題は、以下の順番で行なってください。
・「ステップメール.xls」を開く　＊マクロを有効にする
・VBEを起動する　「Altキー」＋「F11キー」
・「cmd送信」クリック時のプログラムを、一部変更する
・動作確認

以上の図と説明を見ただけで、ステップメールの課題を作成できれば、かなりプログラミングが上達しています。

まずは自力で挑戦してみてください。もし出来なくても、自分の頭で考えてみることが大切です。

ステップごとに挿入する「文章とタイトルをどう扱うか」というのがポイントです。

次回にヒントを掲載します。

【補足】
今回の課題では、ステップごとの時間間隔までは考慮していません。

通常、ステップメールでは、次のステップを送信するまでの時間間隔(1日後、3日後、7日後など)を設定できるものがあります。

でもそこまでの機能を加えると、プログラムが複雑になるので、課題としては難しいと思い、今回は省きました。

したがって、ユーザーが送信作業を行なう間隔が、そのままメール送信間隔になります。

また、ユーザーが「メール送信」ボタンをクリックする度に、ステップが更新されるシンプルな仕組みにします。

]]>